BEGIN "VAR2P"
REQUIRE "PIXHDR.SAI[VIS,HPM]" SOURCE_FILE;
REQUIRE "FILHDR.SAI[VIS,HPM]" SOURCE_FILE;
DEFINE NF=2;
INTEGER MAXL,OCH,I,T;
STRING ARRAY SF[1:NF];   INTEGER ARRAY PIC[1:NF,0:10],PCH[1:NF],OPC[0:10];

WHILE TRUE DO
   BEGIN
   INTEGER RHS1,RHS2,RHW1,RHW2;

   PRSFIL("");
   FOR I←1 STEP 1 UNTIL NF DO
      BEGIN  DO PRINT("BIT FILE ",I,":") UNTIL PFLDIM(SF[I]←INCHWL)>0;
	     PCH[I]←OPNPFL(SF[I],PIC[I,0]);  END;

   MAXL←PIC[1,PCLN];  FOR I←1 STEP 1 UNTIL NF DO MAXL←MAXL MAX PIC[I,PCLN];


   RHS1←PIC[1,LNBY]; IF RHS1=1650+36 THEN RHS1←1700+36;
   RHS2←PIC[2,LNBY]; IF RHS2=1650+36 THEN RHS2←1700+36;
   RHW1←(RHS1+35)%36;  RHW2←(RHS2+35)%36;

   MAKDIM(MAXL,(RHW1+2+RHW2)*36,1,OPC[0]);
   PRINT("OUTPUT FILE:");
   PRSFIL(""); PRSFIL(".VRN"); OCH←CREPFL(OPC[0],INCHWL);

   FOR I←0 STEP 1 UNTIL MAXL-1 DO
       BEGIN
       INTEGER ARRAY SCNLIN[0:200];

       PFLIN(PCH[1],SCNLIN[0],PIC[1,LNWD]);
       PFLIN(PCH[2],SCNLIN[RHW1+2],PIC[2,LNWD]);

       SCNLIN[1]←SCNLIN[1] LOR '400000000000;
       SCNLIN[RHW1-1]←SCNLIN[RHW1-1] LOR ('400000000000 LSH -((RHS1-1) MOD 36));
       SCNLIN[RHW1+3]←SCNLIN[RHW1+3] LOR '400000000000;
       SCNLIN[RHW1+2+RHW2-1]←SCNLIN[RHW1+2+RHW2-1]
                     LOR ('400000000000 LSH -((RHS2-1) MOD 36));
       PFLOUT(OCH,SCNLIN[0],OPC[LNWD]);
       END;

   PFLCLS(OCH);
   PFLCLS(PCH[1]);
   PFLCLS(PCH[2]);
   END;

END "VAR2P";